Adding elementd-desktop-bin since ::gentoo is not up to date yet

net-im/element-desktop-bin/Manifest

@@ -0,0 +1 @@
+DIST element-desktop_1.11.65_amd64.deb 95127376 BLAKE2B d8f22ed48b6acc4145ae17f604c1045f74b6b185505c64c2f1ccc8938f7ec69c149329966f213356542e128d1f294e44eca7d25e22e3012afcaba8d15b4f412e SHA512 c27da6b8def79aa2d2f778257ebdd02e802e2f7bf8e69cd1787cdd239b133ca0426ad0995f705826aae3d5e9927db6272ea7492de863f0831045968aa1346a35

net-im/element-desktop-bin/element-desktop-bin-1.11.65.ebuild

@@ -0,0 +1,83 @@
+# Copyright 2020-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit optfeature unpacker xdg
+
+MY_PN="${PN/-bin}"
+
+DESCRIPTION="A glossy Matrix collaboration client for desktop (binary package)"
+HOMEPAGE="https://element.io"
+SRC_URI="https://packages.element.io/debian/pool/main/e/element-desktop/${MY_PN}_${PV}_amd64.deb"
+S="${WORKDIR}"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+KEYWORDS="amd64"
+RESTRICT="splitdebug"
+
+RDEPEND="
+	>=app-accessibility/at-spi2-core-2.46.0:2
+	app-crypt/libsecret
+	dev-db/sqlcipher
+	dev-libs/expat
+	dev-libs/glib:2
+	dev-libs/nettle
+	dev-libs/nspr
+	dev-libs/nss
+	media-libs/alsa-lib
+	media-libs/mesa
+	net-print/cups
+	sys-apps/dbus
+	x11-libs/cairo
+	x11-libs/gdk-pixbuf:2
+	x11-libs/gtk+:3
+	x11-libs/libX11
+	x11-libs/libXcomposite
+	x11-libs/libXdamage
+	x11-libs/libXext
+	x11-libs/libXfixes
+	x11-libs/libXrandr
+	x11-libs/libdrm
+	x11-libs/libxcb
+	x11-libs/libxkbcommon
+	x11-libs/pango"
+
+QA_PREBUILT="opt/Element/chrome-sandbox
+	opt/Element/chrome_crashpad_handler
+	opt/Element/element-desktop
+	opt/Element/libEGL.so
+	opt/Element/libGLESv2.so
+	opt/Element/libffmpeg.so
+	opt/Element/libvk_swiftshader.so
+	opt/Element/libvulkan.so.1
+	opt/Element/resources/app.asar.unpacked/node_modules/matrix-seshat/index.node
+	opt/Element/resources/app.asar.unpacked/node_modules/keytar/build/Release/keytar.node"
+
+src_prepare() {
+	default
+	rm opt/Element/{LICENSE.electron.txt,LICENSES.chromium.html} || die
+}
+
+src_install() {
+	mv usr/share/doc/${MY_PN} usr/share/doc/${PF} || die
+	gunzip usr/share/doc/${PF}/changelog.gz || die
+
+	insinto /
+	doins -r usr
+	doins -r opt
+	local f
+	for f in ${QA_PREBUILT}; do
+		fperms +x "/${f}"
+	done
+	fperms u+s /opt/Element/chrome-sandbox
+
+	dosym ../../opt/Element/${MY_PN} /usr/bin/${MY_PN}
+	dosym ${MY_PN} /usr/bin/riot-desktop
+}
+
+pkg_postinst() {
+	xdg_pkg_postinst
+	optfeature "emojis" media-fonts/noto-emoji
+}